發現好几起使用http://www.connectify.me/的机器會一直往外丟封包
google了一下
發現這個寫得不錯
記錄一下

call startkey.cmd
@echo off
title 虛擬 WiFi
setlocal

:menu
cls
echo 請選擇 WiFi 設定
echo.
echo 目前虛擬WiFi名稱為 [ %name% ]，密碼為 [ %keys% ] (採用WPA2-PSK加密)
echo.
echo 1.立即啟用虛擬Wifi網路卡 (相當於打開路由器)
echo.
echo 2.設定虛擬WiFi名稱、密碼
echo.
echo 3.開啟 虛擬Wifi網路 (須先建立虛擬Wifi網路卡)
echo.
echo 4.關閉 虛擬Wifi網路卡
echo.
echo 5.移除 虛擬Wifi網路卡
echo.
echo 6.測試是否支援虛擬Wifi網路卡
echo. & echo.
choice /c 123456 /M "請選擇 ?"
echo. & echo.
goto WiFi%errorlevel%


:WiFi1
cls
echo 建立虛擬Wifi網路卡
netsh wlan set hostednetwork mode=allow ssid="%name%" key=%keys%
echo.
echo 現在請開啟「網路和共用中心」，「變更介面卡設定」
echo.
echo 你會看見「Microsoft Virtual WiFi Miniport Adapter」這張虛擬WiFi網路卡
echo.
echo 接下來請選擇要與「虛擬WiFi網路卡」共用網路的連線裝置
echo.
echo 並且打開內容，到「共用」頁面
echo.
echo 勾選「允許其他網路使用者透過這台電腦網際網路連線來連線」
echo.
echo 並將「家用網路連線」選成你的「虛擬Wifi網路卡」
echo.
pause
echo.
echo 啟動虛擬Wifi網路卡
netsh wlan start hostednetwork
echo.
pause
goto end


:WiFi2
cls
echo 允許使用空格
echo.
set /P name=請輸入新名稱　
echo.
echo.
echo 密碼至少要8位
echo.
set /P keys=請輸入新密碼　
echo.
echo 注意將會產生一個startkey.cmd來紀錄你的密碼
echo 若是怕忘記就不要刪除，當然要刪除也是可以(要記得密碼)
echo.
echo set name=%name% > startkey.cmd
echo set keys=%keys% >> startkey.cmd
pause
goto menu

:WiFi3
netsh wlan start hostednetwork
goto end

:WiFi4
netsh wlan stop hostednetwork
goto end

:WiFi5
netsh wlan set hostednetwork mode=disallow
pause
goto end

:WiFi6
netsh wlan show drivers
pause
goto menu

:end
exit
endlocal


http://fangyuchang.blogspot.tw/2012/12/windows-7-wifi.html

這個軟体看來也ok
http://www.mypublicwifi.com/publicwifi/en/index.html